How to determine the version of Update Rollup 1 for Windows 2000 Service Pack 4 (922979)

MORE INFORMATION

Most of the files that Update Rollup 1 for Windows 2000 SP4 (KB891861) replaces are identical in both versions of the update. However, the update does create some differences in the registry entries.

The registry entries that list the version of the files that Update Rollup 1 for Windows 2000 SP4 (KB891861) installs are created in the following location in the registry: The number and the order of the registry subkeys may be different. Subkeys are numbered consecutively, starting at zero (0).

If Update Rollup 1 for Windows 2000 SP4 (KB891861) is installed, one of the following appears under the Filelist subkey for the Fastfat.sys file:

• Version 1 of the update installs Fastfat.sys version 5.0.2195.7006.
• Version 2 of the update installs Fastfat.sys version 5.0.2195.7061.

To determine the version of Update Rollup 1 for Windows 2000 SP4 (KB891861) that is installed on the computer, follow these steps:

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements.

1. Start Notepad.
2. Paste or type the following commands in Notepad:

   @echo off
   cls
   SET _FOUNDIT=NO
   SET _QTARGET=.
   
   if not "%1" == "" SET _QTARGET=%1
   if "%_QTARGET%"=="." goto START
   echo Checking server %_QTARGET% is visible on the network...
   ping %_QTARGET% -n 1 > nul
   if errorlevel 1 goto PINGFAIL
   
   :START
   echo Checking for the presence of the Update Rollup 1...
   reg query "\\%_QTARGET%\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Updates\Windows 2000\SP5\Update Rollup 1" > nul
   if errorlevel 1 goto NOPACK
   
   for /L %%i in (1,1,485) do call :job %%i
   if "%_FOUNDIT%" == "NO" goto NEITHER
   goto DISPLAY
   
   :job
   if "%_FOUNDIT%" == "NO" call :job2 %1
   goto :EOF
   
   :job2
   reg query "\\%_QTARGET%\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Updates\Windows 2000\SP5\Update Rollup 1\Filelist\%1" /v FileName > temp.lst
   findstr /I fastfat.sys temp.lst > nul
   if errorlevel 1 goto :EOF
   SET _FOUNDIT=YES
   reg query "\\%_QTARGET%\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Updates\Windows 2000\SP5\Update Rollup 1\Filelist\%1" /v Version > temp.lst
   goto :EOF
   
   :PINGFAIL
   echo Failed to ping the destination server, aborting.
   goto END
   
   :NOPACK
   echo There was no Update Rollup 1 found on %_QTARGET%
   goto END
   
   :DISPLAY
   findstr /I 5.0.2195.7006 temp.lst > nul
   if errorlevel 1 goto CHKVER2
   echo This machine (%_QTARGET%) has version 1 of the Windows 2000 Rollup 1 installed.
   goto END
   
   :CHKVER2
   findstr /I 5.0.2195.7061 temp.lst > nul
   if errorlevel 1 goto NEITHER
   echo This machine (%_QTARGET%) has version 2 of the Windows 2000 Rollup 1 installed.
   goto END
   
   :NEITHER
   echo Unable to determine the version of the Windows 2000 Rollup 1 installed on %_QTARGET%.
   
   :END
   if exist temp.lst del temp.lst
   

3. On the File menu, click Save As, name the batch file, and then save it to the location of your choice. For this example, name the file Version.bat, and then save it to drive C.
4. Click Start, click Run, type cmd in the Open box, and then click OK.
5. At the command prompt, type C:\file name.bat to run the batch file. For this example, type C:\Version.bat to run the batch file.