HOW TO: Change the Values in a Hyperlink Field from an HTTP Address to a MAILTO Address in Microsoft Access 2000 (323202)

SUMMARY

If you type an e-mail address into a Hyperlink field, the address defaults to an HTTP address for the link. Therefore, if you type someone@example.com, what is actually stored in the database is someone@example.com#http://someone@example.com#

This is expected behavior because a Hyperlink field is made up of two parts: the displayed text, and the actual address. Because the field type is Hyperlink, Access assumes that the text that is entered will be a Web site and not an e-mail address.

To change this so that you can click the hyperlink and send e-mail, you can use either Method 1 or Method 2 mentioned earlier. =Both methods update existing records only.

To automatically format data that is entered into the database, you can use the "How to Store a Properly Formatted E-mail Address Automatically" that is mentioned earlier. back to the top

Method 1

Using an Update Query to Change the HTTP Address to a MAILTO Address

1. Create a query in Design View that is based on the table that has the e-mail addresses.
2. Include just the e-mail field from the table in the query design grid.
3. On the Query menu, click Update Query. This adds the Update To row to the query design grid.
4. In the Update To row, type the following expression. Replace [Mail Field] with the name of your e-mail field:

   IIf(Left([Mail Field],8)<>"#mailto:","#mailto:" & Left([Mail Field],InStr(1,[Mail Field],"#")-1),[Mail Field])

5. On the File menu, click Save. Save the query as qryUpdateHyperlink.
6. On the Query menu, click Run. Note that you receive a message that indicates how many rows (records in the table) will be updated. Click Yes to update your records.

back to the top

Method 2

Using Visual Basic for Applications Code to Change the HTTP Address to a MAILTO Address

NOTE: The sample code in this article uses Microsoft Data Access Objects. For this code to run properly, you must reference the Microsoft DAO 3.6 Object Library. To do so, click References on the Tools menu in the Visual Basic Editor, and make sure that the Microsoft DAO 3.6 Object Library check box is selected.

1. Create a new module and name it basUpdateHyperlinkToMail.
2. Type or paste the following code in the module:

   Sub UpdateHyperlinkToMail()
   On Error GoTo Err_UpdateHyperlinkToMail
       Dim DB As DAO.Database
       Dim RS As DAO.Recordset
       Dim strMail As String
       
       Set DB = CurrentDb
       Set RS = DB.OpenRecordset("E-mail Table", dbOpenDynaset)
       
       With RS
           If .RecordCount > 0 Then .MoveFirst
           Do Until .EOF
               If Not IsNull(![Hyperlink Field]) Then
                   If Left(![Hyperlink Field], 8) <> "#mailto:" Then
                       strMail = "#mailto:" & Left(![Hyperlink Field], _
                       InStr(1, ![Hyperlink Field], "#") - 1) & "#"
                       .Edit
                           ![Hyperlink Field] = strMail
                       .Update
                   End If
               End If
               .MoveNext
           Loop
       End With
       MsgBox "Update complete!"    
   
   Exit_UpdateHyperlinkToMail:
       RS.Close
       Set RS = Nothing
       Set DB = Nothing
       Exit Sub
       
   Err_UpdateHyperlinkToMail:
       MsgBox "Error: " & Err.Number & " - " & Err.Description
       Resume Exit_UpdateHyperlinkToMail
   End Sub
   					

3. Replace the "E-Mail Table" text in the code with the correct name of your table, and replace all instances of the text [Hyperlink Field] with the name of your field that has the e-mail addresses.
4. Click the pointer somewhere in this procedure, and then press F5 to run the code.

back to the top

Storing a Properly Formatted E-mail Address Automatically

In the future, if you want to store the e-mail addresses that you enter as an e-mail link instead of a hyperlink to an Internet page, follow these steps. This process requires that the data is entered through a form.

1. Open your data entry form in Design View.
2. Right-click the field that you use to enter the e-mail address, and then click Properties.
3. In the Properties dialog box, click the Event tab.
4. Click in the AfterUpdate property box, click the arrow, and then click [Event Procedure] in the list.
5. Click the Build (...) button to start the Visual Basic Editor.
6. What you see in the Visual Basic Editor depends on the name of your e-mail field. For example, if the name of your e-mail field is Text0, you see the following:

   Private Sub Text0_AfterUpdate()
   
   End Sub

7. Type or paste the two following lines of code between the two lines of code shown in step 6. Make sure to replace [Text0] with the name of your field.

   If Len(Me![Text0]) = 0 Then Exit Sub 
   Me![Text0] = "#mailto:" & Left(Me![Text0], InStr(1, Me![Text0], "#") - 1) & "#"

   Whenever an e-mail address is now entered in this field, it is automatically formatted and stored as an e-mail address as soon as focus has moved away from this field.

back to the top