SharePoint Portal Server Portal Backup Files Are Indexed and Appear in Search Results (314162)

WORKAROUND

1. Remove the Portal.backup folder.
   
   NOTE: Do not remove the Portal.backup folder until you update any customizations that may be removed after you apply SharePoint Portal Server SP1.
2. Secure the Portal.backup folder so that only administrators or coordinators can view the Portal.backup folder.
3. Turn off indexing of the Portal.backup folder. The following script turns off indexing of the folder. Save the script to a .vbs file to run the script:

Dim InfoNT, oWorkspaceFolder, oBackupFolder, oRS1, oRS2

 
Set InfoNT = CreateObject("WinNTSystemInfo")
Set oWorkspaceFolder = CreateObject("CDO.KnowledgeFolder")
Set oBackupFolder = CreateObject("CDO.KnowledgeFolder")

oWorkspaceFolder.DataSource.Open "http://" & InfoNT.ComputerName & "/SharePoint Portal Server/workspaces/"

Set oRS1 = CreateObject("ADODB.Recordset")
Set oRS2 = CreateObject("ADODB.Recordset")

Set oRS1 = oWorkspaceFolder.SubFolders 'Get list of workspaces on server

While Not oRS1.EOF 'Turn off indexing of Portal.Backup folder and sub folders
  if not oRS1.Fields("DAV:IsHidden") then 'Only process non-hidden folders in /SharePoint Portal Server/workspaces/ 
    SetNoIndex oRS1.Fields("DAV:href") & "/Portal/Portal.Backup"
    oBackupFolder.DataSource.Open oRS1.Fields("DAV:href") & "/Portal/Portal.Backup"
    Set oRS2 = oBackupFolder.SubFolders
    While Not oRS2.EOF
      SetNoIndex oRS2.Fields("DAV:href")
      oRS2.MoveNext
    Wend
    wscript.echo "Indexing disabled for " & oRS1.Fields("DAV:href") & "/Portal/Portal.Backup"
  End If
  oRS1.MoveNext
Wend


Sub SetNoIndex(strURL)
  Dim Rec, Conn, Flds
  Set Rec = CreateObject("ADODB.Record")
  Set Conn = CreateObject("ADODB.Connection")
 
  Conn.Provider = "ExOLEDB.DataSource"
  Conn.Open strURL
  Rec.Open replace(strURL, "", "%20"), Conn, 3

  Set Flds = Rec.Fields
  Flds("urn:schemas.microsoft.com:fulltextqueryinfo:noindex") = "True"
  Flds.Update
End Sub