How to use the Microsoft Outlook Object Library to create an Outlook contact in Visual Basic .NET (313787)

MORE INFORMATION

1. Start Microsoft Visual Studio .NET.
2. On the File menu, point to New, and then click Project.
3. Under Project Types, click Visual Basic Projects.
4. Under Templates, click Console Application, and then click OK.
   
   By default, Module1.vb is created.
5. Add a reference to the Microsoft Outlook 10.0 Object Library. To do this, follow these steps:
   1. On the Project menu, click Add Reference.
   2. On the COM tab, click Microsoft Outlook 10.0 Object Library, and then click Select.
   3. In the Add References dialog box, click OK to accept your selections. If you receive a prompt to generate wrappers for the libraries that you selected, click Yes.
6. In the code window for Module1, replace all the code with:

   'TO DO: If you use the Microsoft Outlook 11.0 Object Library, uncomment the following line.
   'Imports Outlook = Microsoft.Office.Interop.Outlook
   Imports System.Reflection
   
   Module Module1
   
       Sub Main()
           ' Create an Outlook application.
           Dim oApp As Outlook.Application = New Outlook.Application()
   
           ' Get the namespace and the logon.
           Dim oNS As Outlook.NameSpace = oApp.GetNamespace("MAPI")
           ' TODO: Replace the "YourValidProfile" and "myPassword" with 
           'Missing.Value if you want to log on with the default profile.
           oNS.Logon("YourValidProfile", "myPassword", True, True)
   
           ' Create a new contact item.
           Dim oCt As Outlook.ContactItem = oApp.CreateItem(Outlook.OlItemType.olContactItem)
           oCt.Display(True)  'Modal	
   
           ' Set some common properties.
           oCt.FullName = "David Pelton"
           oCt.Title = "Student"
           oCt.Birthday = Convert.ToDateTime("10/1/1982")
           oCt.CompanyName = "Fourth Coffee "
           oCt.Department = "PSS"
           oCt.Body = "Test Body"
           oCt.FileAs = "David"
           oCt.Email1Address = "abc@hotmail.com"
           oCt.BusinessHomePage = "http://www.fourthcoffee.com/"
           oCt.MailingAddress = "12345 Bellevue"
           oCt.BusinessAddress = "56789 1st. Redmond, WA 98001"
           oCt.OfficeLocation = "666 Office"
           oCt.Subject = "Hello World"
           oCt.JobTitle = "Engineer"
   
           ' Save it to the Contacts folder.
           oCt.Save()
   
           ' Display the created contact item.
           'oCt.Display(True)
   
           ' Log off.
           oNS.Logoff()
   
           ' Clean up.
           oApp = Nothing
           oNS = Nothing
           oCt = Nothing
       End Sub
   
   End Module

7. Search for "TO DO" in the code, and then modify the code for your environment.
8. Press F5 to build and to run the program.
9. Verify that the contact has been created.