XL2000: Using the New Keyword to Create Instances of a UserForm (213709)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact a Microsoft Certified Partner or the Microsoft fee-based consulting line at (800) 936-5200. For more information about Microsoft Certified Partners, please visit the following Microsoft Web site: For more information about the support options that are available and about how to contact Microsoft, visit the following Microsoft Web site:

Creating the Sample UserForm

To create the sample UserForm, follow these steps:

1. Close all open workbooks, and then create a new workbook.
2. Start the Visual Basic Editor (press ALT+F11).
3. On the Insert menu, click UserForm.
4. Add a ListBox control to the lower-left portion of the UserForm.
5. Add a Label control above the ListBox control and change the Caption property to Click an item.
6. Add three CommandButton controls to the right of the ListBox control.
7. Use the following properties for the command buttons:

         Top Command Button:
   
            Property    Value
            -------------------------------
            Name        cmdNewForm
            Caption     create new instance
   
         Middle Command Button:
   
            Property    Value
            ----------------------------
            Name        cmdFormCaption
            Caption     UserForm caption
   
         Bottom Command Button:
   
            Property    Value
            ----------------------
            Name        cmdClose
            Caption     close form
   					

Entering Macro Code

To create the macro, follow these steps:

1. In the Visual Basic Editor, on the Insert menu, click Module.
2. Enter the following code in the General Declarations section of the new module:

   Option Base 1
   ' Counter for instances of UserForms.
   Public mycount As Integer
   
   ' Array containing UserForm objects
   Public MyForms() As UserForm1
   
   Sub New_UserForms()
   
      ' Display the UserForm.
      UserForm1.Show
   
   End Sub
   					

3. Double-click the top command button and enter the following code for the Click event for the cmdNewForm command button:

   Private Sub cmdNewForm_Click()
   
      mycount = mycount + 1
   
      ' Increase the size of the MyForms array by one.
      ReDim Preserve MyForms(mycount)
   
      ' Create a new instance that is of type UserForm1.
      Set MyForms(mycount) = New UserForm1
   
      ' Set the caption of the UserForm to the instance number.
      MyForms(mycount).Caption = "instance " & mycount
   
      MyForms(mycount).cmdClose.Caption = "hide form"
   
      ' Add new item to the list box.
      UserForm1.ListBox1.AddItem mycount
   
   End Sub
   					

4. Double-click the middle command button and enter the following code for the Click event for the cmdFormCaption command button:

   Private Sub cmdFormCaption_click()
   
      ' Display the Caption of the current UserForm.
      MsgBox Me.Caption
   
   End Sub
   					

5. Double-click the bottom command button and enter the following code for the Click event for the cmdClose command button:

   Private Sub cmdClose_Click()
   
      ' Hide the current instance of the UserForm.
      Me.Hide
   
   End Sub
   					

6. Double-click the ListBox control and enter the following code for the MouseUp event:

   Private Sub ListBox1_MouseUp _
   (ByVal Button As Integer, ByVal Shift As Integer, _
   ByVal X As Single, ByVal Y As Single)
   
      ' Display the selected instance of the UserForm.
      MyForms(UserForm1.ListBox1.ListIndex + 1).Show
   
   End Sub
   					

7. Enter the following code for the QueryClose event for UserForm1:

   Private Sub UserForm_QueryClose _
   (Cancel As Integer, CloseMode As Integer)
   
      On Error Resume Next ' Ignore if no forms exist.
   
      ' Setting the value of Cancel to any integer other than 0 prevents
      ' you from clicking the Close ("X") button to close the UserForm.
      Cancel = 1
   
   End Sub
   					

Running the Macros

To run the example macros, follow these steps:

1. Run the New_UserForms macro.
   
   This step displays the UserForm.
2. Click the Create New Instance command button.
   
   Each time you click the Create New Instance command button, a new instance of the UserForm is created, and a new item is added to the list box.
3. Click any number in the list box.
   
   The relevant instance of the UserForm is displayed.
4. Click the UserForm Caption command button.
   
   A message box displays the caption for the currently visible UserForm.
5. Click the Hide Form command button.
   
   The currently visible UserForm is hidden, and UserForm1 is displayed.
   
   NOTE: The caption on the bottom command button was programmatically changed to Hide Form to differentiate it from the bottom button on UserForm1. When you hide one of the created instances of the UserForm, and UserForm1 is active, the caption on the bottom command button is Close Form, which is the value set at design time.
6. If UserForm1 is active, click the Close Form button to stop the macro.