XL2000: Unlocked Cells Not Underlined with Protection Enabled (213661)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. The following Visual Basic macro places a bottom border on all unlocked cells in a worksheet. The macro also removes any bottom border from locked cells. To create the macro:

1. On the Tools menu, point to Macro, and then click Visual Basic Editor.
2. On the Insert menu, click Module.
3. In the module, type the following macro code:

   Sub Format_Unlocked_Cells()
             'Declare procedure-level variables
             Dim x As Range, lastcell As Range, passwrd as String
             ' To use a worksheet password, insert the desired password 
             ' between the quotes below eg:
             ' passwrd = "secret"
             passwrd = ""
   
            'Prevent screen redraw to speed up the macro
             Application.ScreenUpdating = False
   
             'Unprotect the worksheet to allow editing
             ActiveSheet.Unprotect passwrd
   
             'Set lastcell to point to the last cell on the sheet
             Set lastcell = Selection.SpecialCells(xlLastCell)
   
             'Place bottom borders on unlocked cells and remove any bottom
             'borders from locked cells
             For Each x In Range("A1", lastcell)
                 With x.Borders(xlBottom)
                     If x.Locked = False Then
                         .Weight = xlHairline
                         .ColorIndex = xlAutomatic
                     Else
                         .LineStyle = xlNone
                     End If
                 End With
             Next x
   
             'Re-apply worksheet protection.
             ActiveSheet.Protect passwrd
   End Sub

4. On the File menu, click Close and Return to Microsoft Excel.

NOTE: If you want to format a specific cell range, replace Range("A1", lastcell) with the range you want to format, for example, Range("A1:G100").

To use the macro:

1. On the Tools menu, point to Macro, and then click Macros.
2. In the list of macros, select the Format_Unlocked_Cells macro. Click Run.