XL: Visual Basic Module to Create a Gantt Chart (213447)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact a Microsoft Certified Partner or the Microsoft fee-based consulting line at (800) 936-5200. For more information about Microsoft Certified Partners, please visit the following Microsoft Web site: For more information about the support options that are available and about how to contact Microsoft, visit the following Microsoft Web site: To create a Visual Basic for Applications macro in Excel that you can use to create a Gantt chart, follow these steps:

1. Start Excel.
2. Press ALT+F11 to start the Visual Basic Editor.
3. On the Insert menu, click Module.
4. Type or paste the following code in the Visual Basic module sheet:

   Option Explicit
    
   Sub Gantt_Chart()
       'Define the variables.
       Dim rge As String
       Dim ValueAxisMinValue As Date
       Dim shtname As String
       Dim Title As String, aChart As Chart
       'Store the location of the data as a string.
       rge = Selection.Address()
       'Store the start date for the chart.
       ValueAxisMinValue = Selection.Cells(2, 2).Value
       'Ask user for the Chart title.
       Title = InputBox("Please enter the title")
       'Store the sheet name.
       shtname = ActiveSheet.Name
       'Turn off screen updating.
       Application.ScreenUpdating = False
       'Create a chart located on a chart sheet.
       Set aChart = Charts.Add
       With aChart
           .ChartWizard Source:=Sheets(shtname).Range(rge), _
           Gallery:=xlBar, Format:=3, PlotBy:=xlColumns, _
           CategoryLabels:=1, SeriesLabels:=1, HasLegend:=1, _
           Title:=Title, CategoryTitle:="", ValueTitle:="", _
           ExtraTitle:=""
           'Remove the legend.
           .Legend.Delete
           'Create and format the series.
           With .SeriesCollection(1)
               With .Border
                   .Weight = xlThin
                   .LineStyle = xlNone
               End With
               .InvertIfNegative = False
               .Interior.ColorIndex = xlNone
           End With
           'Modify the category (x) axis.
           With .Axes(xlCategory)
               .ReversePlotOrder = True
               .TickLabelSpacing = 1
               .TickMarkSpacing = 1
               .AxisBetweenCategories = True
           End With
           'Modify the value (y) axis.
           With .Axes(xlValue)
               .MinimumScale = ValueAxisMinValue
               .MaximumScaleIsAuto = True
               .MinorUnitIsAuto = True
               .MajorUnitIsAuto = True
               .Crosses = xlAutomatic
               .ReversePlotOrder = False
               .ScaleType = False
               .HasMajorGridlines = True
               .HasMinorGridlines = False
           End With
        End With
       'Turn screen updating back on.
       Application.ScreenUpdating = True
    
    End Sub
   					

5. Press ALT+F11 to return to Excel.

Using the Macro

To use the Gantt_chart macro, follow these steps:

1. In a new Excel worksheet, type the following values:

        A1:            B1: START        C1: DAYS          D1: DAYS
        A2: TASK       B2: DATE         C2: COMPLETED     D2: REMAINING
        A3: TASK-1     B3: 1/1/91       C3: 150           D3: 15
        A4: TASK-2     B4: 5/1/91       C4: 21            D4: 31
        A5: TASK-3     B5: 7/1/91       C5: 0             D5: 114
        A6: TASK-4     B6: 10/1/91      C6: 0             D6: 4
        A7: TASK-5     B7: 10/15/91     C7: 0             D7: 31
        A8: TASK-6     B8: 11/1/91      C8: 0             D8: 2
   					

2. Select cells A2:D8.
3. On the Tools menu, point to Macro, and then click Macros.
4. Click Gantt_chart, and then click Run.
5. Type the chart title when prompted. The Gantt chart is displayed on a new chart sheet. You may add any additional formatting that you want.