XL2000: How to Call a Macro Repeatedly on a Fixed Time Interval (213288)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied, including, but not limited to, the implied warranties of merchantability and/or fitness for a particular purpose. This article assumes that you are familiar with the programming language being demonstrated and the tools used to create and debug procedures. Microsoft support professionals can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific needs. If you have limited programming experience, you may want to contact a Microsoft Certified Partner or the Microsoft fee-based consulting line at (800) 936-5200. For more information about Microsoft Certified Partners, please visit the following Microsoft Web site: For more information about the support options that are available and about how to contact Microsoft, visit the following Microsoft Web site: To call a macro a number of times at a fixed interval, use the steps in the following example:

NOTE: The following example calls a macro four times at a 5-second interval.

1. Start Excel.
2. Press ALT+F11 to start the Visual Basic editor.
3. On the Insert menu, click Module.
4. Type the following code into a new module sheet:

   ' Module level declaration of icount, inumberofcalls. This line
   ' must be at the top of the module sheet
   Dim icount as Integer, inumberofcalls As Integer
   
   Sub StartOnTime()
       ' Initialize icount to 1.
       icount = 1
       ' Initialize inumberofcalls to 4.
       inumberofcalls = 4
       ' Select the range of cells for formatting.
       Range("A2:A" & inumberofcalls + 1).Select
       ' Format the selected cells as time.
       Selection.NumberFormat = "h:mm:ss AM/PM"
       ' Start in cell A1.
       Range("A1").Select
       ' Put the word "Time" in cell A1.
       ActiveCell.Value = "Time"
       ' Start the OnTimeMacro.
       Call OnTimeMacro
   End Sub
   
   Sub OnTimeMacro()
     ' Run the RunEvery5seconds macro inumberofcalls times.
       If icount <= inumberofcalls Then
           ' Run the RunEvery5seconds macro in 5 seconds.
           Application.OnTime Now + TimeValue("00:00:05"), _
               "RunEvery5seconds"
           ' Increment icount by 1.
           icount = icount + 1
       Else
           ' Icount is greater than inumberofcalls, so exit the macro.
           Exit Sub
       End If
   End Sub
   
   Sub RunEvery5seconds()
       ' Places the current time in a cell.
       ActiveCell.Offset(icount - 1, 0).Value = Format(Now(), _
           "hh:mm:ss")
       ' Runs the OnTimeMacro again.
       Call OnTimeMacro
   End Sub
   						

5. Press ALT+F11 to return to Excel.
6. On the Tools menu, point to Macro, and then click Macros.
7. Click StartOnTime, and then click Run.
   
   The macro enters the heading "Time" in cell A1, and then enters each time it runs into cells A2, A3, A4, and A5 on Sheet1 of the active workbook.