WD98: Macro to Generate List of Available Fonts in Word (182793)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. The following sample Visual Basic for Applications macro creates a new blank document, and inserts a sample of each available font:

Sub ListFonts()
      Dim varFont As Variant
      ' Speed macro processing and suppresses display.
      Application.ScreenUpdating = False
      ' Create new document.
      Documents.Add Template:="normal"
      ' Loop through each available font.
      For Each varFont In FontNames
         With Selection
            ' Format name of font.
            .Font.Name = "times new roman"
            .Font.Bold = True
            .Font.Underline = True
            ' Insert Font name.
            .TypeText varFont
            ' Insert a new paragraph after the Font Name.
            .InsertParagraphAfter
            ' Move to the new paragraph.
            .MoveDown unit:=wdParagraph, Count:=1, Extend:=wdMove
            ' Format the font example.
            .Font.Bold = False
            .Font.Underline = False
            .Font.Name = varFont
            ' Enter example text (Alphabetic characters).
            .TypeText "abcdefghijklmnopqrstuvwxyz"
            ' Insert a new paragraph.
            .InsertParagraphAfter
            ' Move to the new paragraph.
            .MoveDown unit:=wdParagraph, Count:=1, Extend:=wdMove
            ' Insert example text (Numeric characters).
            .TypeText "0123456789?$%&()[]*_-=+/<>"
            ' Insert two new paragraphs and move down.
            .InsertParagraphAfter
            .InsertParagraphAfter
            .MoveDown unit:=wdParagraph, Count:=1, Extend:=wdMove
         End With
      Next varFont
      Application.ScreenUpdating = True
   End Sub
				

For additional information, please see the following article in the Microsoft Knowledge Base: