WD98: Creating Hyperlink Deletes Object Reference (182173)

SYMPTOMS

When your Visual Basic for Applications macro creates an object variable that is set to reference a picture object, and if your macro later anchors a hyperlink to the picture object, the object reference is deleted and you receive the following error:

Run-time error '5825': Object has been deleted.

For example, the following Visual Basic for Applications macro adds a hyperlink to an already linked picture. The hyperlink is "anchored" to the picture object referenced by the InLine Picture object variable oILPic. Once the hyperlink is added, the object variable reference, oILPic, is deleted.

      Sub DoInLineShapeHyperlink()
      Dim oDoc As Document
      Dim oILPic As InlineShape
      Dim oHLink As Hyperlink
      Dim sPicFile As String
      Dim sLinkFile as String
      sPicFile = "<Your Graphic File Path and Name>"
      sLinkFile = "<Your HyperLink File Path and Name>"
      ' Create new document.
      Set oDoc = Documents.Add
      ' Insert a picture.
      Set oILPic = oDoc.InlineShapes.AddPicture _
         (Range:=oDoc.Content, FileName:=sPicFile, LinkToFile:=True)
      ' Add a hyperlink for the picture.
      oDoc.Hyperlinks.Add Anchor:=oILPic.Range, Address:=sLinkFile
      ' The error occurs here because oILPic is no longer valid.
      Set oHLink = oILPic.Hyperlink
   End Sub

CAUSE

You receive the "Object has been deleted" error message because the macro has attempted to access an object that has been deleted. The object may have been deleted deliberately, such as with the Delete method. Or, it may have been deleted as a side effect of another operation, such as when a frame is added around an inline shape, When adding a frame around an inline shape, the original inline shape is deleted and a copy of the shape is created inside the frame.

WORKAROUND

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. To work around this problem, reference the object directly, as in the following example:

   Private Sub DoInLineShapeHyperlink()
      Dim oDoc As Document
      Dim oILPic As InlineShape
      Dim oHLink As Hyperlink
      Dim sPicFile As String
      Dim sLinkFile as String
      sPicFile = "<Your Graphic File Path and Name>"
      sLinkFile = "<Your HyperLink File Path and Name>"
      ' Create new document.
      Set oDoc = Documents.Add
      ' Insert a picture.
      Set oILPic = oDoc.InlineShapes.AddPicture _
      (Range:=oDoc.Content, FileName:= sPicFile, LinkToFile:=True)
      ' Add a hyperlink for the picture.
      oDoc.Hyperlinks.Add Anchor:=oILPic.Range, Address:=sLinkFile
      ' Use the InlineShapes Property to reference the object.
      Set oHLink = oDoc.InlineShapes(1).Hyperlink
   End Sub

MORE INFORMATION

You can use the IsObjectValid method to verify that an object still exists. The following example demonstrates the use of this method:

   Sub testObject()
      Dim ilShp As InlineShape
      Set ilShp = ActiveDocument.InlineShapes.Add("C:\Windows\bubbles.bmp")
      MsgBox IsObjectValid(ilShp)     ' This will display True.
      a.Delete
      MsgBox IsObjectValid(ilShp)     ' This will display False.
   End Sub

REFERENCES

For additional information, please see the following article in the Microsoft Knowledge Base:

181058 OFF98: How to Run Sample Code from Knowledge Base Articles

For more information about getting help with Visual Basic for Applications, please see the following article in the Microsoft Knowledge Base:

163435 VBA: Programming Resources for Visual Basic for Applications