PPT: Sample Code to Name a Slide (161392)

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. The following sample code adds a slide to the end of your presentation, names that slide My New Slide, and then changes the background color of just My New Slide.

   Sub NameSlide()

      ' Declare the variables.
      Dim SlideCount, CurrentView As Long
      Dim Changed As Boolean
      Dim Answer As Integer

      ' Code for error trapping.
      On Error Resume Next
      Err.Clear

      ' Count the slides in the presentation.
      SlideCount = ActivePresentation.Slides.Count

      ' Add a new slide to the end of the presentation.
      With ActivePresentation.Slides

         ' Change the name of the slide to My New Slide.
         ' You can name the slide anything you like. You can even
         ' assign the Name property to a string variable.
         .Add(SlideCount + 1, ppLayoutBlank).Name = "My New Slide"

         ' If slide name exists, an error will occur.
         If Err.Number <> 0 Then
            SlideCount = ActivePresentation.Slides.Count
            ActivePresentation.Slides.Range(Array(SlideCount)).Select
            ActiveWindow.Selection.SlideRange.Delete
            MsgBox "The slide name is already being used."
            End
         End If
      End With

      ' Save the current view.
      CurrentView = ActiveWindow.ViewType

      ' Change to slide view.
      If CurrentView <> ppViewSlide Then
         ActiveWindow.ViewType = ppViewSlide
         Changed = True
      Else
         Changed = False
      End If

      ' This code changes the background of the slide called My New Slide.
      With ActivePresentation.Slides("My New Slide")

         ' Stop the slide from following the master.
         .FollowMasterBackground = False

         ' Change the background color.
         With .Background.Fill
            .PresetGradient msoGradientDiagonalDown, 1, msoGradientFog
         End With

      End With

      ' Restore the original view if needed.
      If Changed = True Then

         Answer = MsgBox("Do you want to restore your original view? " _
            , vbQuestion + vbYesNo)

         ' If the answer is yes...
         If Answer = vbYes Then
            ' ...restore the view.
            ActiveWindow.ViewType = CurrentView
         End If
      End If
   End Sub